gun flyer no jets prop or jump

View previous topic View next topic Go down

gun flyer no jets prop or jump

Post by freek4ever on Sun Dec 18, 2011 2:31 pm

How about a plane/hovercraft or somthing that flies no ornocopter powered by guns

No jets no propelor no baloon

Just guns

The time limit is endles

I don care how it fly's but it has to leave te ground by ARM guns

avatar
freek4ever
Tank
Tank

Posts : 97
Join date : 2011-08-26
Age : 21
Location : nederland holand

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by Maurice on Tue Dec 20, 2011 7:33 pm

Do I not recall someone making one of these some time ago?
avatar
Maurice
Hover
Hover

Posts : 153
Join date : 2011-10-07
Age : 22
Location : The early 1970's

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by RA2lover on Wed Dec 21, 2011 5:13 am

i think bwansy made one of those. i never managed to take off with it on flat terrain though.

Code:
// [RCD]
Val
{
   BOOSTER(default=0, max=20000, step=20000)
   ENG1(default=0, max=20000, step=20000)
   ENG2(default=0, max=20000, step=20000)
   ENG3(default=0, max=20000, step=20000)
   ENG4(default=0, max=20000, step=20000)
   PITCH(default=0, min=-5, max=5, step=2)
   ROLL(default=0, min=-15, max=15, step=2)
}
Key
{
   0:PITCH(step=1)
   1:PITCH(step=-1)
   2:ROLL(step=-1)
   3:ROLL(step=1)
   8:BOOSTER(step=20000)
}
Body
{
   Core() {
      E:Trim(angle=-ROLL) {
         E:Chip() {
            E:Trim(angle=ROLL) {
               E:Chip() { }
            }
         }
      }
      W:Trim(angle=-ROLL) {
         W:Chip() {
            W:Trim(angle=ROLL) {
               W:Chip() { }
            }
         }
      }
      S:Chip(angle=PITCH) {
         S:Chip(angle=PITCH) {
            S:Chip(angle=PITCH) {
               S:Chip(angle=PITCH) {
                  S:Arm(power=BOOSTER, option=20000) { }
               }
            }
         }
      }
      N:Frame(angle=90) {
         E:TrimF(angle=90) {
            S:Arm(power=ENG4, option=20000) { }
            E:Frame() {
               S:Arm(power=ENG3, option=20000) { }
               E:Frame() {
                  S:Arm(power=ENG2, option=20000) { }
                  E:Frame() {
                     S:Arm(power=ENG1, option=20000) { }
                  }
               }
            }
         }
         W:TrimF(angle=90) {
            N:Arm(power=ENG4, option=20000) { }
            W:Frame() {
               N:Arm(power=ENG3, option=20000) { }
               W:Frame() {
                  N:Arm(power=ENG2, option=20000) { }
                  W:Frame() {
                     N:Arm(power=ENG1, option=20000) { }
                  }
               }
            }
         }
      }
      N:Frame(angle=-90) {
         E:TrimF(angle=-90) {
            S:Arm(power=ENG1, option=20000) { }
            E:Frame() {
               S:Arm(power=ENG2, option=20000) { }
               E:Frame() {
                  S:Arm(power=ENG3, option=20000) { }
                  E:Frame() {
                     S:Arm(power=ENG4, option=20000) { }
                  }
               }
            }
         }
         W:TrimF(angle=-90) {
            N:Arm(power=ENG1, option=20000) { }
            W:Frame() {
               N:Arm(power=ENG2, option=20000) { }
               W:Frame() {
                  N:Arm(power=ENG3, option=20000) { }
                  W:Frame() {
                     N:Arm(power=ENG4, option=20000) { }
                  }
               }
            }
         }
      }
   }
}
Lua
{local timer = 0;

function main()
   if(_TICKS() < 150) then
      out(1, "Wait...");
   else
      out(1, "Ready");
   end
   if(_KEY(8) == 1 and timer < 3) then
      timer = timer + 1;
   elseif(_KEY(8) == 1 and timer >= 3) then
      timer = 0;
   end
   if(timer == 0) then
      ENG1 = 20000;
      ENG2 = 0;
      ENG3 = 0;
      ENG4 = 0;
      out(0, "Firing engine 1");
   elseif(timer == 1) then
      ENG1 = 0;
      ENG2 = 20000;
      ENG3 = 0;
      ENG4 = 0;
      out(0, "Firing engine 2");
   elseif(timer == 2) then
      ENG1 = 0;
      ENG2 = 0;
      ENG3 = 20000;
      ENG4 = 0;
      out(0, "Firing engine 3");
   elseif(timer == 3) then
      ENG1 = 0;
      ENG2 = 0;
      ENG3 = 0;
      ENG4 = 20000;
      out(0, "Firing engine 4");
   end
   if(_KEY(8) ~= 1) then
      ENG1 = 0;
      ENG2 = 0;
      ENG3 = 0;
      ENG4 = 0;
      out(0, "No engines firing");
   end
end}

EDIT:300th post
avatar
RA2lover
Walker
Walker

Posts : 382
Join date : 2010-10-11
Age : 22
Location : Brazil

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by freek4ever on Wed Dec 21, 2011 10:25 am

lol
avatar
freek4ever
Tank
Tank

Posts : 97
Join date : 2011-08-26
Age : 21
Location : nederland holand

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by JosefYurnov99 on Wed Dec 21, 2011 4:35 pm

Here's my entry.
Zazka ARMjet prototype 01
Z activates power
X shuts off power
I couldn't really get it to take off at the arena unless I threw it off the edge, but once it's in the air it flies great.

Code:

// [RCD]
Val
{
   AIL(default=0, min=-5, max=5, step=5)
   COL(default=#FF8000)
   COL1(default=#2D2D2D)
   FLAPS(default=180, min=160, max=180, step=5)
   JET(default=0, max=40000)
   PITCH(default=0, min=-10, max=10, step=5)
}
Key
{
   0:Pitch(step=-8)
   1:Pitch(step=8)
   2:Ail(step=5)
   3:Ail(step=-5)
   4:Jet(step=40000)
   5:Jet(step=-40000)
   6:FLAPS(step=-5)
}
Body
{
   Core(color=#ff00) {
      W:Trim(angle=Ail, color=Col1) {
         W:Chip(color=Col1) {
            W:Trim(angle=-Ail, color=Col1) { }
         }
      }
      E:Trim(angle=Ail, color=Col1) {
         E:Chip(color=Col1) {
            E:Trim(angle=-Ail, color=Col1) { }
         }
      }
      S:Chip(color=Col1) {
         S:Chip(color=Col1) {
            S:Frame(color=Col1) {
               W:Trim(angle=Pitch, color=Col1) { }
               E:Trim(angle=-Pitch, color=Col1) { }
            }
            S:Trim(angle=90, color=Col1) {
               E:Chip(color=Col1) {
                  N:Cowl(option=4, color=Col1) { }
               }
               N:Cowl(color=Col1) { }
            }
         }
      }
      N:Weight(color=Col1, option=2) {
         W:Rudder(angle=-15, color=Col1) {
            W:Chip(color=Col1) {
               W:Chip(color=Col1) { }
            }
         }
         E:Rudder(angle=15, color=Col1) {
            E:Chip(color=Col1) {
               E:Chip(color=Col1) { }
            }
         }
         N:Frame(color=Col1) {
            N:Frame(color=Col1) {
               N:Frame(color=Col1) {
                  N:Cowl(angle=-175, color=Col) {
                     N:Cowl(color=Col) {
                        N:Cowl(color=Col) {
                           N:Cowl(angle=10, effect=#8000) {
                              N:Cowl(angle=-15, color=Col) {
                                 N:Cowl(angle=-5) {
                                    N:Cowl(color=Col) {
                                       N:Cowl(angle=5, color=Col) { }
                                       W:Cowl(angle=-160, color=Col) { }
                                       E:Cowl(angle=-160, color=Col) { }
                                    }
                                    W:Cowl(angle=-150) { }
                                    E:Cowl(angle=-150) { }
                                 }
                                 W:Cowl(angle=-140, color=Col) { }
                                 E:Cowl(angle=-140, color=Col) { }
                              }
                              E:Cowl(angle=-150, effect=#8000) { }
                              W:Cowl(angle=-150, effect=#8000) { }
                           }
                           E:Cowl(angle=-160, color=Col) { }
                           W:Cowl(angle=-160, color=Col) { }
                        }
                        E:Cowl(angle=-170, color=Col) { }
                        W:Cowl(angle=-170, color=Col) { }
                     }
                     E:Cowl(angle=-170, option=4, color=Col) { }
                     W:Cowl(angle=-170, option=3, color=Col) { }
                  }
                  N:Cowl(angle=175, color=Col) {
                     N:Cowl(color=Col) {
                        N:Cowl(color=Col) {
                           N:Cowl(angle=5, color=Col) {
                              N:Cowl(angle=5, color=Col) {
                                 N:Cowl() {
                                    N:Cowl(color=Col) {
                                       N:Cowl(angle=-5, color=Col) { }
                                       E:Cowl(angle=160, color=Col) { }
                                       W:Cowl(angle=160, color=Col) { }
                                    }
                                    E:Cowl(angle=150) { }
                                    W:Cowl(angle=150) { }
                                 }
                                 E:Cowl(angle=140, color=Col) { }
                                 W:Cowl(angle=140, color=Col) { }
                              }
                              W:Cowl(angle=150, color=Col) { }
                              E:Cowl(angle=150, color=Col) { }
                           }
                           E:Cowl(angle=160, color=Col) { }
                           W:Cowl(angle=160, color=Col) { }
                        }
                        E:Cowl(angle=170, color=Col) { }
                        W:Cowl(angle=170, color=Col) { }
                     }
                     W:Cowl(angle=175, option=3, color=Col) { }
                     E:Cowl(angle=175, option=4, color=Col) { }
                  }
               }
            }
         }
         N:Frame(angle=150) {
            N:Frame(angle=-150) {
               S:Frame() {
                  S:Frame() { }
               }
               N:Frame(angle=-10) { }
            }
         }
      }
      E:Frame(color=Col1) {
         E:Frame(color=Col1) {
            N:Frame(angle=-160, color=Col1) {
               N:Arm(angle=-20, power=JET, option=40000, color=Col1) { }
            }
            N:Frame(angle=160, color=Col1) {
               N:Arm(angle=20, power=JET, option=40000, color=Col1) { }
            }
            E:Frame(color=Col1) {
               N:Frame(angle=-160, color=Col1) {
                  N:Arm(angle=-20, power=JET, option=40000, color=Col1) { }
               }
               N:Frame(angle=160, color=Col1) {
                  N:Arm(angle=20, power=JET, option=40000, color=Col1) { }
               }
            }
         }
      }
      W:Frame(color=Col1) {
         W:Frame(color=Col1) {
            N:Frame(angle=-160, color=Col1) {
               N:Arm(angle=-20, power=JET, option=40000, color=Col1) { }
            }
            N:Frame(angle=160, color=Col1) {
               N:Arm(angle=20, power=JET, option=40000, color=Col1) { }
            }
            W:Frame(color=Col1) {
               N:Frame(angle=160, color=Col1) {
                  N:Arm(angle=20, power=JET, option=40000, color=Col1) { }
               }
               N:Frame(angle=-160, color=Col1) {
                  N:Arm(angle=-20, power=JET, option=40000, color=Col1) { }
               }
            }
         }
      }
   }
}
Script
{
   print 0,"Zazka Classified divison"
   print 1,"Zazka X-265 ARMjet Prototype"
   print 2,"Z & X = Power"

}

avatar
JosefYurnov99
Plane
Plane

Posts : 43
Join date : 2011-03-11
Age : 22
Location : America

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by bwansy on Sat Dec 24, 2011 1:16 am

RA2lover wrote:i think bwansy made one of those. i never managed to take off with it on flat terrain though.

Indeed I have made several of those. In fact, I am pretty confident that I "invented" gun propulsion. Wink

_________________
A.K.A. Bernard

bwansy
Admin

Posts : 170
Join date : 2010-07-15

View user profile http://rigidchips.forum-motion.com

Back to top Go down

Re: gun flyer no jets prop or jump

Post by freek4ever on Sat Dec 24, 2011 4:14 pm

and i posted this chelence before i know them
so show them
avatar
freek4ever
Tank
Tank

Posts : 97
Join date : 2011-08-26
Age : 21
Location : nederland holand

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by bwansy on Mon Dec 26, 2011 6:02 am

Here you go. This is a light plane with a expendable "booster". Too bad it can't take off by itself.

Please not that this plane requires my library pack. I tried to make a "stand-alone" version but it ended up too big.

Code:
// [RCD]
Val
{
   AILEL(default=0, min=-400, max=400, disp=0)
   AILER(default=0, min=-400, max=400, disp=0)
   CANARDL(default=0, min=-400, max=400, disp=0)
   CANARDR(default=0, min=-400, max=400, disp=0)
   ENGTRIG(default=0, max=999999999, step=999999999, disp=0)
   FLAP(default=0, min=-400, max=400, disp=0)
   GA101(default=180, min=-400, max=400, disp=0)
   GA102(default=180, min=-400, max=400, disp=0)
   GA103(default=180, min=-400, max=400, disp=0)
   GA104(default=180, min=-400, max=400, disp=0)
   GA105(default=180, min=-400, max=400, disp=0)
   GA106(default=180, min=-400, max=400, disp=0)
   GA107(default=180, min=-400, max=400, disp=0)
   GA108(default=180, min=-400, max=400, disp=0)
   GA109(default=180, min=-400, max=400, disp=0)
   GA110(default=180, min=-400, max=400, disp=0)
   GA201(default=120, min=-400, max=400, disp=0)
   GA202(default=120, min=-400, max=400, disp=0)
   GA203(default=120, min=-400, max=400, disp=0)
   GA204(default=120, min=-400, max=400, disp=0)
   GA205(default=120, min=-400, max=400, disp=0)
   GA206(default=120, min=-400, max=400, disp=0)
   GA207(default=120, min=-400, max=400, disp=0)
   GA208(default=120, min=-400, max=400, disp=0)
   GA209(default=120, min=-400, max=400, disp=0)
   GA210(default=120, min=-400, max=400, disp=0)
   SPOILL(default=180, min=-400, max=400, disp=0)
   SPOILR(default=180, min=-400, max=400, disp=0)
   STANDANG(default=60, min=-400, max=400, disp=0)
   SWEEP(default=-30, min=-400, max=400, disp=0)
   TRIG101(default=0, max=999999999, step=999999999, disp=0)
   TRIG102(default=0, max=999999999, step=999999999, disp=0)
   TRIG103(default=0, max=999999999, step=999999999, disp=0)
   TRIG104(default=0, max=999999999, step=999999999, disp=0)
   TRIG105(default=0, max=999999999, step=999999999, disp=0)
   TRIG106(default=0, max=999999999, step=999999999, disp=0)
   TRIG107(default=0, max=999999999, step=999999999, disp=0)
   TRIG108(default=0, max=999999999, step=999999999, disp=0)
   TRIG109(default=0, max=999999999, step=999999999, disp=0)
   TRIG110(default=0, max=999999999, step=999999999, disp=0)
}
Key
{
}
Body
{
   Core(name=NOSE, user2=1) {
      S:Chip(user2=1) {
         W:Chip(angle=3, user2=1) {
            W:Rudder(angle=-90, user2=1) {
               W:Arm(power=ENGTRIG, option=100000, user2=1) { }
               E:Chip(angle=SPOILL, user2=1) { }
               E:Chip(angle=-SPOILL, user2=1) { }
            }
            W:Rudder(angle=-SWEEP, user2=1) {
               W:Trim(angle=-AILEL, user2=1) {
                  W:Chip(user2=1) { }
               }
            }
         }
         E:Chip(angle=3, user2=1) {
            E:Rudder(angle=90, user2=1) {
               E:Arm(power=ENGTRIG, option=100000, user2=1) { }
               W:Chip(angle=SPOILR, user2=1) { }
               W:Chip(angle=-SPOILR, user2=1) { }
            }
            E:Rudder(angle=SWEEP, user2=1) {
               E:Trim(angle=AILER, user2=1) {
                  E:Chip(user2=1) { }
               }
            }
         }
         N:Frame(angle=25, user2=1) {
            N:Frame(angle=-25, user2=1) {
               N:Frame(user2=1) {
                  N:Chip(user2=1) {
                     E:Trim(angle=CANARDR, user2=1) { }
                     W:Trim(angle=-CANARDL, user2=1) { }
                  }
               }
            }
         }
         N:Chip(angle=STANDANG, name=GUNMOUNT) {
            N:Chip() {
               N:Weight() { }
            }
         }
      }
      S:Jet(angle=45, name=GUNBASE) {
         S:Jet(angle=-135) {
            S:Frame(angle=150) {
               S:Frame(angle=GA101) {
                  S:Arm(angle=GA201, power=TRIG101, option=1600000, name=GUN101) { }
               }
               S:Frame(angle=GA102) {
                  S:Arm(angle=GA202, power=TRIG102, option=1600000, name=GUN102) { }
               }
               S:Frame(angle=GA103) {
                  S:Arm(angle=GA203, power=TRIG103, option=1600000, name=GUN103) { }
               }
               S:Frame(angle=GA104) {
                  S:Arm(angle=GA204, power=TRIG104, option=1600000, name=GUN104) { }
               }
               S:Frame(angle=GA105) {
                  S:Arm(angle=GA205, power=TRIG105, option=1600000, name=GUN105) { }
               }
               S:Frame(angle=GA106) {
                  S:Arm(angle=GA206, power=TRIG106, option=1600000, name=GUN106) { }
               }
               S:Frame(angle=GA107) {
                  S:Arm(angle=GA207, power=TRIG107, option=1600000, name=GUN107) { }
               }
               S:Frame(angle=GA108) {
                  S:Arm(angle=GA208, power=TRIG108, option=1600000, name=GUN108) { }
               }
               S:Frame(angle=GA109) {
                  S:Arm(angle=GA209, power=TRIG109, option=1600000, name=GUN109) { }
               }
               S:Frame(angle=GA110) {
                  S:Arm(angle=GA210, power=TRIG110, option=1600000, name=GUN110) { }
               }
            }
            N:Frame(angle=150) {
               N:Frame(angle=GA101) {
                  N:Arm(angle=GA201, power=TRIG101, option=1600000, name=GUN201) { }
               }
               N:Frame(angle=GA102) {
                  N:Arm(angle=GA202, power=TRIG102, option=1600000, name=GUN202) { }
               }
               N:Frame(angle=GA103) {
                  N:Arm(angle=GA203, power=TRIG103, option=1600000, name=GUN203) { }
               }
               N:Frame(angle=GA104) {
                  N:Arm(angle=GA204, power=TRIG104, option=1600000, name=GUN204) { }
               }
               N:Frame(angle=GA105) {
                  N:Arm(angle=GA205, power=TRIG105, option=1600000, name=GUN205) { }
               }
               N:Frame(angle=GA106) {
                  N:Arm(angle=GA206, power=TRIG106, option=1600000, name=GUN206) { }
               }
               N:Frame(angle=GA107) {
                  N:Arm(angle=GA207, power=TRIG107, option=1600000, name=GUN207) { }
               }
               N:Frame(angle=GA108) {
                  N:Arm(angle=GA208, power=TRIG108, option=1600000, name=GUN208) { }
               }
               N:Frame(angle=GA109) {
                  N:Arm(angle=GA209, power=TRIG109, option=1600000, name=GUN209) { }
               }
               N:Frame(angle=GA110) {
                  N:Arm(angle=GA210, power=TRIG110, option=1600000, name=GUN210) { }
               }
            }
            E:Trim(angle=90) {
               S:Rudder(angle=-20) {
                  S:Chip() { }
               }
            }
            W:Trim(angle=90) {
               N:Rudder(angle=-20) {
                  N:Chip() { }
               }
            }
         }
      }
   }
}
Lua
{require("Bernard/Aero.lua")


function init()
   clist = {}
   for i = 0,_CHIPS()-1 do
      if _USER2(i) == 1 then
         table.insert(clist,i)
      end
   end

   mouseflag = 1
   engflag = 0
   flapflag = 0
   flapfac = 0
   
   keybrake = 0
   
   pitch = {i = 0, p = 0, d = 0}
   roll = {i = 0, p = 0, d = 0}
   
   apitch = 0
   aroll = 0
   
   yaw_filter = 0
   yaw_alpha = 0.1
   
   numgun = 10
   guncount = numgun
   phase = 0
   gaset = 80
   gunspd = 15
   gbdelay = 2
   gb = {}
   for i = 1,numgun do
      table.insert(gb,-1)
   end
end
function OnInit()
   init()
end
function OnReset()
   init()
end

function sumpid(pid)
   return pid.i+pid.p+pid.d
end

function inputctrl()
   mouseflag = switch(mouseflag,15)
   if phase >= 2 then
      engflag = switch(engflag,16)
      flapflag = switch(flapflag,12)
   end
   flapfac = animate(flapfac,flapflag,0.05)
   
   if mouseflag > 0 then
      mx,my = inputmouse(0)
   else
      mx,my = 0,0
   end
   keybrake = animate(keybrake,_KEY(11),0.05)
   
   inppitch = sgn(my)*abs(my)^1.5
   inproll = sgn(mx)*abs(mx)^1.5
   inpbrake = keybrake
end

function getstate()
   st = getstatefull(NOSE,clist,st)
   st.alpha = atan2(-st.v.y,-st.v.z)
   st.beta = atan2(st.v.x,-st.v.z)
   st.ex,st.ey,st.ez = vtr3.euler(NOSE)
   wt = st.m*9.81
end

function CSAS()
   pcorr = vcorr(st.v.z,0.0,0.15)
   
   rcorr = vcorr(st.v.z,0.0,0.2)
   vlock = ctrllock(vtr3.mag(st.v),5,10)
   
   betalock = ctrllock(st.v.z,5,10)
   
   pitchset = inppitch*2
   
   pitch.i = limit(pitch.i+0.6*pcorr*(pitchset+st.w.x),-3,3)*vlock
   pitch.p = 2.5*pcorr*(pitchset+st.w.x)*vlock
   pitch.d = 0.01*st.dw.x*pcorr*vlock
   pitcht = sumpid(pitch)
   
   rollset = inproll*3.5

   roll.i = limit(roll.i+0.2*rcorr*(rollset+st.w.z),-3,3)*vlock
   roll.p = 1.8*rcorr*(rollset+st.w.z)*vlock
   roll.d = 0.01*st.dw.z*rcorr*vlock
   rollt = sumpid(roll)
   
   spoilf = inpbrake*pcorr
   
   yaw_filter = yaw_filter*(1-yaw_alpha)+st.w.y*yaw_alpha
   yaw_filter2 = yaw_filter+st.w.y
   keyyaw = _KEY(4)-_KEY(6)
   yawt = (yaw_filter2*2.5*pcorr+st.beta*3)*betalock
   flapf = flapfac*15
end

function fire()
   guncharge = _E(GUN101)/_OPTION(GUN101)
   if guncharge == 1 and _KEYDOWN(7) > 0 then
      phase = 1
      _BYE(GUNMOUNT)
   end
   
   for i = 1,numgun do
      if gb[i] > 0 then gb[i] = gb[i]-1 end
      if gb[i] == 0 then
         for j = 1,2 do
            _BYE(_G["GUN"..(j*100+i)]-1)
         end
      end
   end
   if gb[1] == 0 then _BYE(GUNBASE) end
   
   if phase == 1 then
      if guncount > 0 then
      _G["GA"..(200+guncount)] = animate(_G["GA"..(200+guncount)],0,gunspd)
      _G["GA"..(100+guncount)] = 300-_G["GA"..(200+guncount)]
      if _G["GA"..(200+guncount)] <= gaset then
         _G["TRIG"..(100+guncount)] = 999999999
         gb[guncount] = gbdelay
         guncount = guncount-1
      end
      else
         phase = 2
      end
   end
end

function actuate()
   SWEEP = animate(SWEEP,-30,1)
   CANARDL = animate(CANARDL,limit(-pitcht*30,-30,30),10)
   CANARDR = animate(CANARDR,limit(-pitcht*30,-30,30),10)
   aroll = animate(aroll,limit(rollt*50,-30,30),10)
   SPOILL = 180+limit(sqrt(spoilf+limit(yawt,0,1))*50,0,40)
   SPOILR = 180+limit(sqrt(spoilf+limit(-yawt,0,1))*50,0,40)
   AILEL = limit(-aroll+flapf,-50,50)
   AILER = limit(aroll+flapf,-50,50)
   
   FLAP = flapfac*15
   
   ENGTRIG = engflag*999999999
end

function OnFrame()
   inputctrl()
   getstate()
   if phase == 2 then
   CSAS()
   actuate()
   end
   fire()
   _ZOOM(55)
   
   STANDANG = limit(STANDANG+(_KEY(1)-_KEY(0))*0.5,30,90)
   out(10,STANDANG)
   out(0,"Pulse launcher by Bernard (bwansy)")
   if phase == 0 then
      out(1,string.format("Charge: %4i %%",guncharge*100))
      out(2,"Press [A] to launch")
   elseif phase == 1 then
      out(1,"Booster firing")
   elseif phase == 2 then
      out(1,"[F] Flaps [B] Brakes")
      out(2,"[E] Toggle engines")
   end
end}

_________________
A.K.A. Bernard

bwansy
Admin

Posts : 170
Join date : 2010-07-15

View user profile http://rigidchips.forum-motion.com

Back to top Go down

Re: gun flyer no jets prop or jump

Post by Maurice on Mon Dec 26, 2011 3:16 pm

Here's my entry. I kinda cheated on the launching mechanism (it uses jets, but they are ejected).However, once it's up in the air, it's completely powered by guns.

Code:
 // [RCD]
Val
{
   AIL(default=0, min=-15, max=15, step=5)
   E(default=0, max=1)
   ELEV(default=0, min=-15, max=15, step=5)
   G1(default=0, max=100000, step=100000)
   G2(default=0, max=100000, step=100000)
   G3(default=0, max=100000, step=100000)
   G4(default=0, max=100000, step=100000)
   LAUNCH(default=0, max=50000)
   TIMER(default=-1, min=-1, max=100, step=100)
}
Key
{
   0:Elev(step=5)
   1:Elev(step=-5)
   2:ail(step=-5)
   3:ail(step=5)
   4:E(step=1), Launch(step=50000)
   5:E(step=-1)
}
Body
{
   Core(name=core) {
      S:Chip(color=#0D0D0D) {
         S:Chip(color=#0D0D0D) {
            S:Trim(angle=90, color=#0D0D0D) {
               E:Chip(color=#0D0D0D) {
                  N:Cowl(option=4, color=#0D0D0D) { }
               }
               N:Cowl(color=#0D0D0D) {
                  N:Cowl(color=#0D0D0D) { }
               }
               S:Frame(name=M5) {
                  S:Wheel() { }
               }
            }
            S:Chip(color=#0D0D0D) {
               E:Trim(angle=Elev, color=#0D0D0D) { }
               W:Trim(angle=-elev, color=#0D0D0D) { }
            }
         }
      }
      N:Frame() {
         N:Frame() {
            W:Frame(option=1) {
               S:Chip(angle=ail, color=#0D0D0D) {
                  W:Chip(color=#0D0D0D) { }
                  S:Frame(angle=30, name=m1) {
                     S:Jet(angle=-120, power=Launch) { }
                  }
                  W:Frame(angle=60, name=M3) {
                     W:Wheel(angle=30) { }
                  }
               }
            }
            E:Frame(option=1) {
               S:Chip(angle=-ail, color=#0D0D0D) {
                  E:Chip(color=#0D0D0D) { }
                  S:Frame(angle=30, name=m2) {
                     S:Jet(angle=-120, power=Launch) { }
                  }
                  E:Frame(angle=60, name=M4) {
                     E:Wheel(angle=30) { }
                  }
               }
            }
            W:RudderF(angle=-27, option=1) {
               W:Chip(color=#0D0D0D) { }
               N:Cowl(angle=180, color=#0D0D0D) { }
            }
            E:RudderF(angle=27, option=1) {
               E:Chip(color=#0D0D0D) { }
               N:Cowl(angle=180, color=#0D0D0D) { }
            }
            N:Cowl() {
               N:Cowl(angle=-150, effect=#6000) {
                  N:Cowl(angle=-20, effect=#6000) {
                     N:Cowl(angle=-10, color=#0D0D0D) {
                        N:Cowl(angle=-9.7, color=#0D0D0D) {
                           N:Cowl(color=#0D0D0D) {
                              N:Cowl(color=#0D0D0D) {
                                 N:Cowl(color=#0D0D0D) {
                                    E:Cowl(angle=-160, option=3, color=#0D0D0D) { }
                                    W:Cowl(angle=-160, option=4, color=#0D0D0D) { }
                                 }
                                 E:Cowl(angle=-160, color=#0D0D0D) {
                                    S:Cowl(color=#0D0D0D) { }
                                 }
                                 W:Cowl(angle=-160, color=#0D0D0D) {
                                    S:Cowl(color=#0D0D0D) { }
                                 }
                              }
                              W:Cowl(angle=-90, option=4, color=#0D0D0D) { }
                              E:Cowl(angle=-90, option=3, color=#0D0D0D) { }
                              E:Cowl(angle=-150, color=#0D0D0D) { }
                              W:Cowl(angle=-150, color=#0D0D0D) { }
                           }
                           W:Cowl(angle=-90, color=#0D0D0D) { }
                           E:Cowl(angle=-90, color=#0D0D0D) {
                              N:Cowl(angle=-90, color=#0D0D0D) { }
                           }
                           S:Cowl(angle=-80, color=#0D0D0D) { }
                        }
                        W:Cowl(angle=-90, color=#0D0D0D) { }
                        E:Cowl(angle=-90, color=#0D0D0D) { }
                     }
                     E:Cowl(angle=-91, effect=#6000) { }
                     W:Cowl(angle=-91, effect=#6000) { }
                  }
                  W:Cowl(angle=-91, option=3, effect=#6000) { }
                  E:Cowl(angle=-91, option=4, effect=#6000) { }
                  S:Cowl(angle=-160, color=#808080) {
                     S:Cowl(angle=60, color=#808080) { }
                  }
               }
               N:Cowl(angle=150, color=#0D0D0D) {
                  N:Cowl(angle=20, color=#0D0D0D) {
                     N:Cowl(angle=10, color=#0D0D0D) {
                        N:Cowl(angle=9.7, color=#0D0D0D) {
                           N:Cowl(color=#0D0D0D) {
                              N:Cowl(color=#0D0D0D) {
                                 N:Cowl(color=#0D0D0D) {
                                    E:Cowl(angle=160, option=3, color=#0D0D0D) { }
                                    W:Cowl(angle=160, option=4, color=#0D0D0D) { }
                                 }
                                 E:Cowl(angle=160, color=#0D0D0D) {
                                    S:Cowl(color=#0D0D0D) { }
                                 }
                                 W:Cowl(angle=160, color=#0D0D0D) {
                                    S:Cowl(color=#0D0D0D) { }
                                 }
                              }
                              W:Cowl(angle=90, option=4, color=#0D0D0D) { }
                              E:Cowl(angle=90, option=3, color=#0D0D0D) { }
                              E:Cowl(angle=150, color=#0D0D0D) { }
                              W:Cowl(angle=150, color=#0D0D0D) { }
                           }
                           W:Cowl(angle=90, color=#0D0D0D) { }
                           E:Cowl(angle=90, color=#0D0D0D) {
                              N:Cowl(angle=90, color=#0D0D0D) { }
                           }
                        }
                        W:Cowl(angle=90, color=#0D0D0D) { }
                        E:Cowl(angle=90, color=#0D0D0D) { }
                     }
                     E:Cowl(angle=90, option=4, color=#0D0D0D) { }
                     W:Cowl(angle=90, option=3, color=#0D0D0D) { }
                     N:Cowl(angle=90, option=5, color=#804000) { }
                  }
                  W:Cowl(angle=90, option=3, color=#0D0D0D) {
                     N:Cowl(option=4, color=#0D0D0D) { }
                  }
                  E:Cowl(angle=90, option=4, color=#0D0D0D) {
                     N:Cowl(option=3, color=#0D0D0D) { }
                  }
               }
               S:Cowl(option=1) {
                  S:Cowl(color=#0D0D0D) { }
               }
            }
         }
         W:Frame(option=1) {
            W:Frame(color=#0D0D0D) {
               N:Frame(angle=-150, option=1) {
                  N:Frame(angle=150, option=1) {
                     S:Arm(power=G2, option=100000, color=#800000) {
                        E:Cowl(angle=90, color=#800000) {
                           N:Cowl(angle=30, option=5, color=#0D0D0D) { }
                        }
                        N:Cowl(angle=30, option=5, color=#0D0D0D) { }
                     }
                  }
               }
               N:Frame(angle=150, option=1) {
                  N:Frame(angle=-150, option=1) {
                     W:Frame(angle=-90, option=1) {
                        S:Arm(power=G3, option=100000, color=#800000) {
                           N:Cowl(angle=-30, option=5, color=#0D0D0D) { }
                        }
                     }
                     S:Arm(power=G1, option=100000, color=#800000) {
                        N:Cowl(angle=-30, option=5, color=#0D0D0D) { }
                     }
                  }
               }
            }
         }
         E:Frame(option=1) {
            E:Frame(color=#0D0D0D) {
               N:Frame(angle=-150, option=1) {
                  N:Frame(angle=150, option=1) {
                     E:Frame(angle=90, option=1) {
                        S:Arm(power=G3, option=100000, color=#800000) {
                           N:Cowl(angle=30, option=5, color=#0D0D0D) { }
                        }
                     }
                     S:Arm(power=G2, option=100000, color=#800000) {
                        W:Cowl(angle=90, color=#800000) {
                           N:Cowl(angle=30, option=5, color=#0D0D0D) { }
                        }
                        N:Cowl(angle=30, option=5, color=#0D0D0D) { }
                     }
                  }
               }
               N:Frame(angle=150, option=1) {
                  N:Frame(angle=-150, option=1) {
                     S:Arm(power=G1, option=100000, color=#800000) {
                        N:Cowl(angle=-30, option=5, color=#0D0D0D) { }
                     }
                  }
               }
            }
         }
      }
   }
}
Script
{print 0, "Gun powered Aircraft Mk I"
print 1, "Z & X - Power"
print 2, "S - Eject Launching Equipment"

if TIMER=(0){
G1=(100000)
}

if TIMER=(7){
G2=(100000)
}

if TIMER=(14){
G3=(100000)
}

if TIMER=(21){
TIMER=(-1)}

If E=1 {
   Timer=Timer+1
}
If E=0 {
   Timer=-1
}
If _H(core)>10 {
   _BYE(M1)
}
If _H(core)>10 {
   _BYE(M2)
}
If _H(core)>10 {
   _SPLIT(M3)
}
If _H(core)>10 {
   _SPLIT(M4)
}
If _H(core)>10 {
   _SPLIT(M5)
}}
avatar
Maurice
Hover
Hover

Posts : 153
Join date : 2011-10-07
Age : 22
Location : The early 1970's

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by freek4ever on Mon Dec 26, 2011 3:51 pm

Just jet for take of is fine all I have seen don't take of by it self so press y ore r is fine

Ore make an arm (no gun ) that trows the plane is also an idea


avatar
freek4ever
Tank
Tank

Posts : 97
Join date : 2011-08-26
Age : 21
Location : nederland holand

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by Maurice on Fri Dec 30, 2011 10:30 am

The reason I used jets for take-off instead of arms is that when you are on a server full of angry Japanese people with spam cannons, taking off quickly is almost a necessity. Arms just take too long to charge.
avatar
Maurice
Hover
Hover

Posts : 153
Join date : 2011-10-07
Age : 22
Location : The early 1970's

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by RA2lover on Sat Dec 31, 2011 7:34 am

you're invulnerable for the first 150 frames(which enable arms to be fired)
avatar
RA2lover
Walker
Walker

Posts : 382
Join date : 2010-10-11
Age : 22
Location : Brazil

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by Maurice on Sat Jan 07, 2012 12:54 pm

I did not know that, I could use this knowledge to my advantage. However, the power that would be required to launch it with an arm would just be too much and would take too long to charge.
avatar
Maurice
Hover
Hover

Posts : 153
Join date : 2011-10-07
Age : 22
Location : The early 1970's

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by freek4ever on Thu Apr 12, 2012 9:29 am

bwansy i dont have the lua
avatar
freek4ever
Tank
Tank

Posts : 97
Join date : 2011-08-26
Age : 21
Location : nederland holand

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by darkeye22 on Thu Apr 12, 2012 9:33 am

avatar
darkeye22
Tank
Tank

Posts : 55
Join date : 2011-06-01
Location : Stuck inside RigidChips trying to find a way out

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by freek4ever on Thu Apr 12, 2012 9:43 am

the winer is Maurice
bekows his plan flys very goed and it looks good
second is JosefYurnov99 it is great but it shoks very mutch
turt is bwansy first it is an gun plane but it is hard to keap it in the air

and bwansy last dint work wit lua
congratulations
avatar
freek4ever
Tank
Tank

Posts : 97
Join date : 2011-08-26
Age : 21
Location : nederland holand

View user profile

Back to top Go down

Re: gun flyer no jets prop or jump

Post by Sponsored content


Sponsored content


Back to top Go down

View previous topic View next topic Back to top

- Similar topics

 
Permissions in this forum:
You cannot reply to topics in this forum