R-66B

View previous topic View next topic Go down

R-66B

Post by Echo_Delta_Oscar on Wed Mar 07, 2012 8:30 am



This plane is incredibly heavy at first sight. The reason is, I usually play with limited fuel, and to extend the autonomy of the aircraft I fitted it with 7 option 4 weights in 3 detachable clusters, obtaining 400% more fuel than the clean airframe.
However, to enable it to take off, I installed 2 JATO unit, to propell it at 120 m/s, in order to take off from the majority of the maps of RC, including the standard (although you'll have to jump off the tennis court situated in the northern side), the Carrier and Battle of Britain (both available at Waffle Productions).
As usual, arrow keys for roll, pitch and trim (with AUTO LEVEL),
A/D for yaw and rudder (with AUTO LEVEL)
F to deploy/retract landing gear
E for brakes and airbrakes
C to release all auxiliary tanks
G to toggle AUTO LEVEL and
Z to toggle the new AHAP, ALTITUDE HOLD AUTOPILOT (AUTO LEVEL must be ON), wich holds the plane at the altitude you pressed Z button (it is adjustable using trim, though).

Code:


Val
{
   RollE(default=0,min=-25,max=25,step=4)
   RollW(default=0,min=-25,max=25,step=4)
   PBar(default=0,min=-30,max=30,step=4)
   Pitch(default=0,min=-30,max=30)
   Yaw(default=0, min=-20, max=20, step=2)
   Rudd(default=0, min=-20, max=20, step=0)
   Ster(default=0, min=-20, max=20)
   Trim(default=0, min=-360, max=360, step=0)
   Throttle(default=0, min=0, max=148500, step=0)
   Engine(default=0, min=0, max=150000, step=0)
   Chocke(default=0, min=0, max=1500, step=0)
   Ign(default=0)
   Gear(default=0, min=0, max=1, step=0)
   Gear1(default=180, min=90, max=180)
   Gear2(default=30, min=-180, max=30)
   Gear3(default=60, min=60, max=180)
   ALVL(default=0, min=0, max=1, step=0)
   AALT(default=0, min=0, max=1, step=0)
   Ypar(default=0)
   BRK(default=0, min=0, max=200, step=200)
   ABR(default=180, min=135, max=180, step=3)
   Smoke(default=1, min=1, max=4)
   JATO(default=0, max=100000)
   Col1(default=#050510)
   Col1C(default=#151520)
   Col2(default=#801010)
   Col2C(default=#a02020)

   
}

Key
{
   15:Throttle(step=1500)
   8:Throttle(step=-1500)
   7:Yaw(step=-2)
   9:Yaw(step=2)
   2:RollE(step=4), RollW(step=-4)
   3:RollE(step=-4), RollW(step=4)
   0:PBar(step=4)
   1:PBar(step=-4)
   16:BRK(step=10), ABR(step=-15)
   
   
   
   
   
}

Body {
   Core(){

      S:Chip(color=Col1C){

      S:Cowl(color=Col1){S:Cowl(color=Col1){}}

      E:Chip(angle=7, color=Col1C){

      N:Cowl(option=4, color=Col1){}
      S:Cowl(angle=1, color=Col1){S:Cowl(angle=-1, color=Col1){}}

      E:Rudder(angle=20, color=Col1C){
      N:RudderF(name=TankE, angle=-20, option=1){
      S:Jet(name=J1, angle=100, power=-JATO, effect=3){}
      E:Weight(angle=83, option=4){S:Weight(option=4){S:Trim(angle=45){}S:Trim(angle=-45){}}}}

      S:Cowl(color=Col1){S:Cowl(color=Col1){}}

      E:Chip(color=Col1C){

      S:Cowl(color=Col1){S:Cowl(option=3, color=Col1){}}

      E:Chip(color=Col2C){

      E:Cowl(option=3, color=Col2){}

      E:Frame(name=EW, option=1){}S:Chip(angle=RollE, color=Col1C){E:Chip(color=Col1C){}}}}}}
      W:Chip(angle=7, color=Col1C){

      N:Cowl(option=3, color=Col1){}
      S:Cowl(angle=1, color=Col1){S:Cowl(angle=-1, color=Col1){}}

      W:Rudder(angle=-20, color=Col1C){
      N:RudderF(name=TankW, angle=20, option=1){
      S:Jet(name=J2, angle=100, power=-JATO, effect=3){}
      W:Weight(angle=83, option=4){S:Weight(option=4){S:Trim(angle=45){}S:Trim(angle=-45){}}}}

      S:Cowl(color=Col1){S:Cowl(color=Col1){}}

      W:Chip(color=Col1C){

      S:Cowl(color=Col1){S:Cowl(option=4, color=Col1){}}

      W:Chip(color=Col2C){

      W:Cowl(option=4, color=Col2){}

      W:Frame(name=WW, option=1){}S:Chip(angle=RollW, color=Col1C){W:Chip(color=Col1C){}}}}}}}
      S:Frame(angle=145, option=1){S:Frame(option=1){S:Frame(angle=-145, option=1){

      S:Cowl(angle=-90, option=1){
      S:Cowl(angle=90, color=Col1){}
      E:Cowl(angle=90, color=Col1){E:Cowl(angle=30, color=Col1){}}
      W:Cowl(angle=90, color=Col1){W:Cowl(angle=30, color=Col1){}}}
      S:Cowl(color=Col1){}

      S:Weight(name=Tank, option=4){N:Weight(option=4){}S:Weight(option=4){
      S:Trim(angle=45){}S:Trim(angle=-45){}}}
      N:Frame(option=1){

      S:Cowl(angle=-90, option=1){
      S:Cowl(angle=45, effect=#a000){E:Cowl(angle=92, effect=#a000){}W:Cowl(angle=92, effect=#a000){}
      S:Cowl(angle=60, effect=#a000){E:Cowl(angle=92, effect=#a000){}W:Cowl(angle=92, effect=#a000){}
      S:Cowl(effect=#a000){E:Cowl(angle=92, effect=#a000){}W:Cowl(angle=92, effect=#a000){}
      S:Cowl(effect=#a000){E:Cowl(angle=92, effect=#a000){}W:Cowl(angle=92, effect=#a000){}}}}}
      S:Cowl(angle=120, color=Col1){}
      E:Cowl(angle=90, color=Col1){}
      W:Cowl(angle=90, color=Col1){}}
      S:Cowl(color=Col1){}

      S:TrimF(angle=90, option=1){E:RudderF(angle=Gear1, option=1){

      W:Cowl(angle=180, option=5, color=Col1){}

      E:TrimF(angle=Ster, option=1){E:Wheel(angle=180, effect=2, brake=Gear){}}}}
      N:Weight(name=Nose, color=Col1C){

      N:Cowl(angle=-30, color=Col2){}
      N:Cowl(angle=-90, option=1){
      N:Cowl(angle=120, color=Col2){S:Cowl(angle=30, color=Col1){}}
      E:Cowl(angle=90, option=5, color=Col2){W:Cowl(color=Col1){}}
      W:Cowl(angle=90, option=5, color=Col2){E:Cowl(color=Col1){}}}
      S:Cowl(angle=-90, option=1){
      S:Cowl(angle=90, color=Col1){}
      E:Cowl(angle=90, color=Col1){}
      W:Cowl(angle=90, color=Col1){}}
      S:Cowl(color=Col1){}
      }}

      S:Frame(option=1){
      S:Frame(option=1){
      S:Frame(option=1){
      E:Frame(angle=Gear2, option=1){

      W:Cowl(angle=180, option=5, color=Col1){}

      E:Wheel(angle=Gear3, effect=2, brake=BRK){}}
      W:Frame(angle=Gear2, option=1){

      E:Cowl(angle=180, option=5, color=Col1){}

      W:Wheel(angle=Gear3, effect=2, brake=BRK){}}
      S:Jet(angle=-90, power=Engine, effect=Smoke){

      E:Cowl(angle=-80, color=Col1){S:Cowl(angle=-95, color=Col1){}N:Cowl(angle=-95, color=Col1){}
      E:Cowl(color=Col1){S:Cowl(angle=-95, color=Col1){}N:Cowl(angle=-95, color=Col1){}
      E:Cowl(color=Col2){S:Cowl(angle=-95, color=Col2){}N:Cowl(angle=-95, color=Col2){}}}}
      W:Cowl(angle=-80, color=Col1){S:Cowl(angle=-95, color=Col1){}N:Cowl(angle=-95, color=Col1){}
      W:Cowl(color=Col1){S:Cowl(angle=-95, color=Col1){}N:Cowl(angle=-95, color=Col1){}
      W:Cowl(color=Col2){S:Cowl(angle=-95, color=Col2){}N:Cowl(angle=-95, color=Col2){}}}}
      E:Cowl(angle=85, color=Col1){S:Cowl(angle=95, color=Col1){}N:Cowl(angle=95, color=Col1){}
      E:Cowl(color=Col1){S:Cowl(angle=95, color=Col1){}N:Cowl(angle=95, color=Col1){}
      E:Cowl(color=Col1){E:Cowl(angle=15, option=5, color=#000000){}E:Cowl(angle=155, option=5, color=#400505){}
      S:Cowl(angle=95, color=Col1){E:Cowl(angle=15, option=5, color=#000000){}E:Cowl(angle=155, option=5, color=#400505){}}
      N:Cowl(angle=95, color=Col1){E:Cowl(angle=15, option=5, color=#000000){}E:Cowl(angle=155, option=5, color=#400505){}}}}}
      W:Cowl(angle=85, color=Col1){S:Cowl(angle=95, color=Col1){}N:Cowl(angle=95, color=Col1){}
      W:Cowl(color=Col1){S:Cowl(angle=95, color=Col1){}N:Cowl(angle=95, color=Col1){}
      W:Cowl(color=Col1){W:Cowl(angle=15, option=5, color=#000000){}W:Cowl(angle=155, option=5, color=#400505){}
      S:Cowl(angle=95, color=Col1){W:Cowl(angle=15, option=5, color=#000000){}W:Cowl(angle=155, option=5, color=#400505){}}
      N:Cowl(angle=95, color=Col1){W:Cowl(angle=15, option=5, color=#000000){}W:Cowl(angle=155, option=5, color=#400505){}}}}}}

      S:Frame(name=Tail, option=1){
      E:Rudder(angle=20, color=Col1C){

      E:Cowl(color=Col2){E:Cowl(option=3, color=Col2){S:Cowl(option=4, color=Col2){}}}

      S:Chip(angle=Pitch, color=Col1C){E:Chip(color=Col1C){

      E:Cowl(option=3, color=Col1){}}}}

      W:Rudder(angle=-20, color=Col1C){

      W:Cowl(color=Col2){W:Cowl(option=4, color=Col2){S:Cowl(option=3, color=Col2){}}}

      S:Chip(angle=Pitch, color=Col1C){W:Chip(color=Col1C){

      W:Cowl(option=4, color=Col1){}}}}

      S:Trim(angle=90, color=Col1C){
      N:Chip(angle=ABR, color=Col1C){}N:Chip(angle=-ABR, color=Col1C){}
      E:Rudder(angle=20, color=Col1C){

      E:Cowl(color=Col1){E:Cowl(color=Col2){E:Cowl(option=3, color=Col2){S:Cowl(color=Col2){}}}}

      S:Chip(angle=Yaw, color=Col1C){E:Chip(color=Col1C){

      E:Cowl(color=Col1){}}}}}
      }}}}
      }}}

}}

Script(){

   print 0,"Thanks for flying my aircrafts!"
   print 2,"Power at ", (Throttle+Chocke)/1500,"%"
   print 3,"Speed: ", _VEL()*3600/1852," knots, ",_VEL()," m/s"
   print 5,"Mass: ",_WEIGHT()," kg, Fuel:",_FUEL()
   print 6,"Fuel LVL: ",_FUEL()/405000,"%"
   print 7,"Heading: ",_TODEG(_AY())


   print 15,"Route Home: ",90-_TODEG(_ATAN2(_Z(), _X()))
   print 16,"Distance Home: ", _LEN2(_Z(),_X()), " m"
   print 9,"Trim: ",Trim,", Rudd: ",Rudd

   Ign=_MOD(Ign+_KEYDOWN(5),2)

   if Ign=(1){
   Chocke=1500
   Engine=(Throttle+Chocke)/(1+_VEL()/400)/(1+_ABS(_Y()-500)/4500)}

   if Ign=(0){
   Engine=0}

   if Throttle>(140000){
   JATO=JATO+1000}

   if _VEL()>(120){
   _BYE(J1)}

   if _VEL()>(120){
   _BYE(J2)}

   ALVL=_MOD(ALVL+_KEYDOWN(13),2)
   AALT=_MOD(AALT+_KEYDOWN(4),2)

   if _KEY(0)>(0) & ALVL=(0) &_TODEG(_EZ())<(65) &_TODEG(_EZ())>(-65){
   Pitch=Pbar
   Trim=_TODEG(_AX())}

   if _KEY(1)>(0) & ALVL=(0) &_TODEG(_EZ())<(65) &_TODEG(_EZ())>(-65){
   Pitch=Pbar
   Trim=_TODEG(_AX())}

   if _KEY(0)=(0) & _KEY(1)=(0) & ALVL=(0) &_TODEG(_EZ())<(65) &_TODEG(_EZ())>(-65){
   Pitch=PBar+(-Trim+_TODEG(_AX()))/(1+_VEL()/50)}

   if _TODEG(_EZ())>(65){
   Pitch=Pbar}

   if _TODEG(_EZ())<(-65){
   Pitch=PBar}

   Gear=_MOD(Gear+_KEYDOWN(12),2)
   if Gear=(0){
   Gear1=Gear1+1
   Gear2=Gear2+7/3
   Gear3=Gear3-2/3
   Ster=Yaw}

   if Gear=(1){
   Gear1=Gear1-1
   Gear2=Gear2-7/3
   Gear3=Gear3+2
   Ster=0
   BRK=BRK+1}

   if ALVL=(1) & AALT=(0){
   Yaw=Rudd
   Pitch=-Trim+_TODEG(_AX())
   RollE=-_TODEG(_AZ())-Yaw*4-_VY(EW)
   RollW=_TODEG(_AZ())+Yaw*4-_VY(WW)
   print 12,"AUTO LEVEL ON"}

   if AALT=(0){
   Ypar=_Y(Control)}

   if ALVL=(1){
   Yaw=Rudd
   RollE=-_TODEG(_AZ())-Yaw*2-_VY(EW)
   RollW=_TODEG(_AZ())+Yaw*2-_VY(WW)
   print 12,"AUTO LEVEL ON"}

   if ALVL=(1) & AALT=(1) & _ABS(Ypar-_Y())<20{
   Ypar=Ypar+Trim/100
   Pitch=((_Y())-(Ypar+3))+_TODEG(_AX())+(_VY(Nose)-_VY(Tail))
   print 13,"ALTITUDE HOLD AP, FL: ", Ypar," m"}

   if ALVL=(1) & AALT=(1) & Ypar-_Y()>20{
   Ypar=Ypar+Trim/100
   Pitch=-23+_TODEG(_AX())+(_VY(Nose)-_VY(Tail))
   print 13,"ALTITUDE HOLD AP, FL: ", Ypar," m"}

   if ALVL=(1) & AALT=(1) & Ypar-_Y()<(-20){
   Ypar=Ypar+Trim/100
   Pitch=23+_TODEG(_AX())+(_VY(Nose)-_VY(Tail))
   print 13,"ALTITUDE HOLD AP, FL: ", Ypar," m"}
   if ALVL=(1) & _KEY(9)>0{
   Rudd=Rudd+1/4}

   if ALVL=(1) & _KEY(7)>0{
   Rudd=Rudd-1/4}

   if ALVL=(1) & _KEY(0)>0{
   Trim=Trim-1/2}

   if ALVL=(1) & _KEY(1)>0{
   Trim=Trim+1/2}

   if ALVL=(0){
   Rudd=0
   print 12,"AUTO LEVEL OFF"}

   if Engine>(0){
   Smoke=1}

   if Engine>(20000){
   Smoke=2}

   if Engine>(75000){
   Smoke=3}

   if Engine>(100000){
   Smoke=4}

   if _KEY(6)>(0){
   _BYE(Tank)}

   if _KEY(6)>(0){
   _BYE(TankE)}

   if _KEY(6)>(0){
   _BYE(TankW)}

   if _KEY(4)>(0){
   Trim=0}

}


Warnings:

1-When selecting AHAP, Trim value should be low, beacuse Z resets it to zero.
2-If option 8 is checked, the plane takes off nicely without auxiliary tanks.
3-LUA is not likely to work on my PC. Thus, if anyone is willing to convert it, for efficiency's sake, he will be welcome.

Enjoy your flight!
avatar
Echo_Delta_Oscar
Hover
Hover

Posts : 105
Join date : 2011-03-24

View user profile

Back to top Go down

Re: R-66B

Post by Maurice on Wed Mar 07, 2012 6:57 pm

I too have a plane with JATO. However, the JATO units on my plane are attached at 45 degree angles to the fuselage. Maybe you could try that on this plane. If you can get it balanced correctly, you could cut the take-off distance in half. My plane is about 50% heavier than yours is and has an IMMENSE take-off run, but with the JATO it can take-off from inside the Arena.
avatar
Maurice
Hover
Hover

Posts : 153
Join date : 2011-10-07
Age : 22
Location : The early 1970's

View user profile

Back to top Go down

Re: R-66B

Post by Echo_Delta_Oscar on Thu Mar 08, 2012 9:33 am

Tried it, works fine.

Thanks for the hint!
avatar
Echo_Delta_Oscar
Hover
Hover

Posts : 105
Join date : 2011-03-24

View user profile

Back to top Go down

Re: R-66B

Post by Maurice on Thu Mar 08, 2012 2:47 pm

No problem.
avatar
Maurice
Hover
Hover

Posts : 153
Join date : 2011-10-07
Age : 22
Location : The early 1970's

View user profile

Back to top Go down

Re: R-66B

Post by Sponsored content


Sponsored content


Back to top Go down

View previous topic View next topic Back to top


 
Permissions in this forum:
You cannot reply to topics in this forum